» Заголовок инсталлятора

K.A.V.
www.oszone.net
22.02.2010
Автор: kotkovets
Последнее обновление: 5.09.2010


Заголовок - это "верхняя" (на картинке) часть инсталлятора.

  

Команда MUI_HEADERIMAGE позволяет отображать картинку.
!define MUI_HEADERIMAGE
По умолчанию: ${NSISDIR}\Contrib\Graphics\Header\nsis.bmp

  

Чтобы добавить свою картинку пишем:
!define MUI_HEADERIMAGE_BITMAP "Моя картинка.bmp"
Рекомендуемый размер картинки 150x57

Чтобы добавить картинку справа пишем:
!define MUI_HEADERIMAGE_RIGHT

Команда MUI_BGCOLOR (цвет: RRGGBB шестнадцатеричный) задаёт цвет фона заголовка страниц «Приветствия» и «Завершения»
define MUI_BGCOLOR "FFFFE3" #здесь цвет бледно-желтый
По умолчанию: FFFFFF

Команда MUI_PAGE_HEADER_TEXT позволяет поместить свой текст в верхний контрол.
Команда MUI_PAGE_HEADER_SUBTEXT позволяет поместить свой текст в нижний контрол.
!define MUI_PAGE_HEADER_TEXT "Справочник по NSIS"
!define MUI_PAGE_HEADER_SUBTEXT "Выберите наш справочник по NSIS"
Учтите надписи будут только на первой странице, кроме страницы «Приветствия» !

Можно также изменять цвет и шрифт надписи-заголовка:

!include "MUI2.nsh"

!define MUI_HEADERIMAGE
!define MUI_PAGE_HEADER_TEXT "Справочник по NSIS"
!define MUI_PAGE_HEADER_SUBTEXT "Выберите наш справочник по NSIS"
!define MUI_HEADER_TRANSPARENT_TEXT  # Устанавливает прозрачный фон для надписи-заголовка

!define MUI_CUSTOMFUNCTION_GUIINIT MyGUIInit

!insertmacro MUI_PAGE_DIRECTORY
!insertmacro MUI_PAGE_COMPONENTS
!insertmacro MUI_PAGE_INSTFILES

!insertmacro MUI_LANGUAGE "Russian"

Name "Программы"
OutFile "Header.exe"

Function MyGUIInit
 !include "WinMessages.nsh"
 GetDlgItem $R0 $HWNDPARENT 1037         # получаем указатель на элемент
 GetDlgItem $R1 $HWNDPARENT 1038         # получаем указатель на элемент
 SetCtlColors $R0 0xFF8040 transparent   # цвет текста зеленый, фон прозрачный
 SetCtlColors $R1 0x00FF00 transparent   # цвет текста красный, фон прозрачный
 CreateFont $1 "Verdana" 10 400          # создаём шрифт
 SendMessage $R0 ${WM_SETFONT} $1 0      # применяем созданный шрифт
 CreateFont $1 "Verdana" 8 400 /ITALIC   # создаём наклонный шрифт
 SendMessage $R1 ${WM_SETFONT} $1 0      # применяем созданный шрифт
FunctionEnd

Section -Post
SectionEnd

# 1037 это элемент текста верхнего контрола
# 1038 это элемент текста нижнего контрола