» LOG-файл установки

K.A.V.
www.oszone.net
22.02.2010
Автор: K.A.V.
Последнее обновление: 22.02.2010

Данный пример позволяет вам создать LOG-файл установки (команды, которые отображаются на странице прогресса установки)

Сначала пропишем глобальные переменные
!define LVM_GETITEMCOUNT 0x1004
!define LVM_GETITEMTEXT 0x102D

В самую последнюю секцию (-POST) прописываем
push "$DESKTOP\LOG.log"
Call DumpLog
Где "$DESKTOP\LOG.log" - путь файла, в который будет происходить запись данных

И необходимо добавить саму функцию записи данных
Function DumpLog
  Exch $5
  Push $0
  Push $1
  Push $2
  Push $3
  Push $4
  Push $6

  FindWindow $0 "#32770" "" $HWNDPARENT
  GetDlgItem $0 $0 1016
  StrCmp $0 0 error
  FileOpen $5 $5 "w"
  StrCmp $5 0 error
    SendMessage $0 ${LVM_GETITEMCOUNT} 0 0 $6
    System::Alloc ${NSIS_MAX_STRLEN}
    Pop $3
    StrCpy $2 0
    System::Call "*(i, i, i, i, i, i, i, i, i) i \
      (0, 0, 0, 0, 0, r3, ${NSIS_MAX_STRLEN}) .r1"
    loop: StrCmp $2 $6 done
      System::Call "User32::SendMessageA(i, i, i, i) i \
        ($0, ${LVM_GETITEMTEXT}, $2, r1)"
      System::Call "*$3(&t${NSIS_MAX_STRLEN} .r4)"
      FileWrite $5 "$4$\r$\n"
      IntOp $2 $2 + 1
      Goto loop
    done:
      FileClose $5
      System::Free $1
      System::Free $3
      Goto exit
  error:
    MessageBox MB_OK error
  exit:
    Pop $6
    Pop $4
    Pop $3
    Pop $2
    Pop $1
    Pop $0
    Exch $5
FunctionEnd